用户名: 密码: 忘记密码? 注册

对.lds连接脚本文件的分析

作者:  时间: 2010-12-30

本文由Jacky原创,来自http://blog.chinaunix.net/u1/58780/showart.php?id=462971

对于.lds文件,它定义了整个程序编译之后的连接过程,决定了一个可执行程序的各个段的存储位置。虽然现在我还没怎么用它,但感觉还是挺重要的,有必要了解一下。

先看一下GNU官方网站上.lds文件形式的完整描述:

SECTIONS {
...
secname start BLOCK(align) (NOLOAD) : AT ( ldadr )
  { contents } >region :phdr =fill
...
}

secnamecontents是必须的,其他的都是可选的。下面挑几个常用的看看:

1secname:段名

2contents:决定哪些内容放在本段,可以是整个目标文件,也可以是目标文件中的某段(代码段、数据段等)

3start:本段连接(运行)的地址,如果没有使用ATldadr),本段存储的地址也是startGNU网站上说start可以用任意一种描述地址的符号来描述。

4ATldadr):定义本段存储(加载)的地址。

看一个简单的例子:(摘自《2410完全开发》)

/* nand.lds */
SECTIONS {
firtst 0x00000000 : { head.o init.o }
second 0x30000000 : AT(4096) { main.o }
}

    以上,head.o放在0x00000000地址开始处,init.o放在head.o后面,他们的运行地址也是0x00000000,即连接和存储地址相同(没有AT指定);main.o放在40960x1000,是AT指定的,存储地址)开始处,但是它的运行地址0x30000000,运行之前需要从0x1000(加载处)复制到0x30000000(运行处),此过程也就用到了读取Nand flash

这就是存储地址和连接(运行)地址的不同,称为加载时域和运行时域,可以在.lds连接脚本文件中分别指定。

编写好的.lds文件,在用arm-linux-ld连接命令时带-Tfilename来调用执行,如
arm-linux-ld Tnand.lds x.o y.o o xy.o。也用-Ttext参数直接指定连接地址,如
arm-linux-ld Ttext 0x30000000 x.o y.o o xy.o

 

既然程序有了两种地址,就涉及到一些跳转指令的区别,这里正好写下来,以后万一忘记了也可查看,以前不少东西没记下来现在忘得差不多了。。。

ARM汇编中,常有两种跳转方法:b跳转指令、ldr指令向PC赋值。

我自己经过归纳如下:

(1)       b step1 b跳转指令是相对跳转,依赖当前PC的值,偏移量是通过该指令本身bit[23:0]算出来的,这使得使用b指令的程序不依赖于要跳到的代码的位置,只看指令本身。

(2)       ldr pc, =step1 :该指令是从内存中的某个位置(step1)读出数据并赋给PC,同样依赖当前PC的值,但是偏移量是那个位置(step1)的连接地址(运行时的地址),所以可以用它实现从FlashRAM的程序跳转。

(3)       此外,有必要回味一下adr伪指令,U-boot中那段relocate代码就是通过adr实现当前程序是在RAM中还是flash中。仍然用我当时的注释:

relocate: /* 把U-Boot重新定位到RAM */
    adr r0, _start /* r0是代码的当前位置 */
/* adr伪指令,汇编器自动通过当前PC的值算出 如果执行到_start时PC的值,放到r0中:
当此段在flash中执行时r0 = _start = 0;当此段在RAM中执行时_start = _TEXT_BASE(在board/smdk2410/config.mk中指定的值为0x33F80000,即u-boot在把代码拷贝到RAM中去执行的代码段的开始) */

    ldr r1, _TEXT_BASE /* 测试判断是从Flash启动,还是RAM */
/* 此句执行的结果r1始终是0x33FF80000,因为此值是又编译器指定的(ads中设置,或-D设置编译器参数) */
    cmp r0, r1 /* 比较r0和r1,调试的时候不要执行重定位 */

    下面,结合u-boot.lds看看一个正式的连接脚本文件。这个文件的基本功能还能看明白,虽然上面分析了好多,但其中那些GNU风格的符号还是着实让我感到迷惑。。。

OUTPUT_FORMAT("elf32­littlearm", "elf32­littlearm", "elf32­littlearm")
  ;指定输出可执行文件是elf格式,32位ARM指令,小端
OUTPUT_ARCH(arm)
  ;指定输出可执行文件的平台为ARM
ENTRY(_start)
  ;指定输出可执行文件的起始代码段为_start.
SECTIONS
{
        . = 0x00000000 ; 从0x0位置开始
        . = ALIGN(4) ; 代码以4字节对齐
        .text : ;指定代码段
        {
          cpu/arm920t/start.o (.text) ; 代码的第一个代码部分
          *(.text) ;其它代码部分
        }
        . = ALIGN(4)
        .rodata : { *(.rodata) } ;指定只读数据段
        . = ALIGN(4);
        .data : { *(.data) } ;指定读/写数据段
        . = ALIGN(4);
        .got : { *(.got) } ;指定got段, got段式是uboot自定义的一个段, 非标准段
        __u_boot_cmd_start = . ;把__u_boot_cmd_start赋值为当前位置, 即起始位置
        .u_boot_cmd : { *(.u_boot_cmd) } ;指定u_boot_cmd段, uboot把所有的uboot命令放在该段.
        __u_boot_cmd_end = .;把__u_boot_cmd_end赋值为当前位置,即结束位置
        . = ALIGN(4);
        __bss_start = .; 把__bss_start赋值为当前位置,即bss段的开始位置
        .bss : { *(.bss) }; 指定bss段
        _end = .; 把_end赋值为当前位置,即bss段的结束位置
}

xloader是在系统上电之后,执行完ROM中的frimware后最先开始执行的用户程序,它的体积很小,执行的功能也很简单,主要是对系统时钟以及外部SDRAM进行初始化,初始化完成之后就检查Flash中的uboot image是否准备好,如果准备好了就将Flash中的uboot image根据image header中指定的load address加载到外部SDRAM中,然后就跳转到uboot执行代码。

这里,我试图从头开始,在源代码级别上来分析整个系统的引导过程。

像Xloader或者uboot之类的程序,并不像我们平常写的应用程序那样,程序的入口函数直接找main函数就行。对于这种系统程序,在最开始看代码,尤其是要找到最开始执行的代码的位置的时候,最好的一个方法就是找到整个工程的.lds文件,也就是链接脚本文件(linker loader script)。它定义了整个工程在编译之后的链接过程,以及各个输入目标文件中的各个段在输出目标文件中的分布。详细的关于lds文件的介绍可以参考 gnu的在线文档:http://sourceware.org/binutils/docs/ld/index.html。其中的第三节Linker Script对链接脚本文件进行了介绍。

现在,我们首先开看一看xloader.lds的代码:



OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(XLOADER_ENTRY)
SECTIONS
{
    . = 0x00000000;
    . = ALIGN(4);
    .text :
    {
      ./obj/init.o (.text)
      *(.text)
    }
 
    .rodata . :
        {
                *(.rodata)
        }
 
        . = ALIGN(4);
 
     
    .data : { *(.data) }
    . = ALIGN(4);
    .got : { *(.got) }
      
    . = ALIGN(4);
    __bss_start = .;
    .bss : { *(.bss) }
    _end = .;
}

下面,我们对这一段代码逐句进行分析。

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
在GNU的文档中,是这么定义的:
OUTPUT_FORMAT(default, big, little),在链接的时候,如果使用了-EB的命令行参数,则使用这里的big参数指定的字节序,如果使用了-EL的命令行参数,则使用这里的little参数指定的字节序,如果没有使用任何命令行参数,则使用这里的default参数指定的字节序。
由xloader.lds中的定义可见,不管在链接的时候使用了何种命令行参数,输出的目标文件都是使用elf32-littlearm方式的字节序。

OUTPUT_ARCH(arm)
在GNU的文档中,是这么定义的:
OUTPUT_ARCH(bfdarch),也就是指定了目标的体系结构,在这里,SpearPlus内部使用的处理器核是arm926ejs的,因此体系结构也就是arm。

ENTRY(XLOADER_ENTRY)
在GNU的文档中,是这么定义的:
ENTRY(symbol)
There are several ways to set the entry point. The linker will set the entry point by trying each of the following methods in order, and stopping when one of them succeeds:
    * the `-e
' entry command-line option;
    * the ENTRY(symbol) command in a linker script;
    * the value of the symbol start, if defined;
    * the address of the first byte of the `.text'
section, if present;
    * The address 0.
也就是说,ENTRY(XLOADER_ENTRY)定义了整个程序的入口处,也就是在标号XLOADER_ENTRY处。整个程序将从这里开始运行。

接下来的部分,是对整个输出目标文件中各个段的存储位置的定义。
在GNU的文档中,是这么定义的:
SECTIONS
     {
       sections-command
       sections-command
       ...
     }
对于其中的每一个sections-command,其完整的定义如下:
The full description of an output section looks like this:

     section [address] [(type)] :
       [AT(lma)] [ALIGN(section_align)] [SUBALIGN(subsection_align)]
       {
         output-section-command
         output-section-command
         ...
       } [>region] [AT>lma_region] [:phdr :phdr ...] [=fillexp]

Most output sections do not use most of the optional section attributes.
The whitespace around section is required, so that the section name is unambiguous. The colon and the curly braces are also required. The line breaks and other white space are optional.
下面来看看xloader.lds中SECTIONS的定义:
SECTIONS
{
    /* location counter设置为0x00000000,其实由于在Makefile中的
     * 链接选项中使用了-Ttext $(TEXT_BASE),而TEXT_BASE=0xD2800B00
     * 因此,此处的设置其实是没有作用的,代码运行的时候将运行在TEXT_BASE地址
     */
    . = 0x00000000;
    . = ALIGN(4); /* 四字节对齐 */
    /* 将所有输入目标文件中的.text段即代码段放在此处,并且,输出目标文件中的.text段中的
     * 开头部分存放init.o的.text段。也就是运行的第一条代码,也就是XLOADER_ENTRY
     * 标号对应的代码就在init.o当中
     */
    .text :
    {
      ./obj/init.o (.text)
      *(.text)
    }
 
    /* 紧接着.text段,存放所有输入目标文件中的.rodata段,也就是
     * 只读数据段。此处注意.rodata后跟着的.,这个.表示当前location counter,
     * 对应于上述完整描述sections中的[address]
     * 此处表示.rodata段紧接着.text段存放,而不用任何对齐
     */
    .rodata . :
        {
                *(.rodata)
        }
 
        . = ALIGN(4); /* 四字节对齐 */
 
     
    /* 将所有输入目标文件中的.data读写数据段存储在此处
     * 所有全局手动初始化的变量存储在该段中,并且在输出目标文件中已经分配了存储空间
     */
    .data : { *(.data) }
    . = ALIGN(4); /* 四字节对齐 */
    /* .got段是GLOBAL OFFSET TABLE,具体的作用还没有搞清楚 */
    .got : { *(.got) }
      
    . = ALIGN(4); /* 四字节对齐 */
    /* .bss段的开始,所有全局未初始化变量的大小等信息存储在该段中
     * 但是在输出的目标文件中并不为这些变量分配存储空间,
     * 而是交给操作系统在初始化的时候分配内存,然后紧跟在.data段后面并初始化为零
     * 另外,此处还定义了两个标号分别表示.bss的开始和结束(也是整个目标文件的结束)
     */
    __bss_start = .;
    .bss : { *(.bss) }
    _end = .;
}

从这里,我们能够得到的最关键的信息是:整个程序的入口在标号XLOADER_ENTRY处,并且该标号定义在init.o目标文件中,因为整个最终的链接之后的目标文件中,位于最开头的就是init.o目标文件。
于是,我们可以根据这个线索来继续追踪整个的引导过程了。


参考文章:
对.lds连接脚本文件的分析
http://blog.csdn.net/tony821224/archive/2008/01/18/2051755.aspx
Documentation for binutils 2.18--ld
http://sourceware.org/binutils/docs/ld/index.html
.bss段和.data段的区别
http://www.w3china.org/blog/more.asp?name=FoxWolf&id=29997
什么是bss段
http://blog.csdn.net/bobocheng1231/archive/2008/02/23/2115289.aspx